Попов Андрей Викторович
Шрифт:
//В первом элементе коллекции содержится буква диска,
//во втором - сетевое имя ресурса и т.д.
s+=NetwDrives(i)+" "+NetwDrives(i+1)+"\n";
i=i+2;
}
WScript.Echo(s); //Выводим сформированные строки на экран
/****** Вывод списка всех подключенных сетевых принтеров ******/
s="Подключенные сетевые принтеры:\n\n";
//Создаем коллекцию с данными о подключенных принтерах
NetwPrinters = WshNetwork.EnumPrinterConnections;
i=0;
while (i<=NetwPrinters.Count-2) { //Перебираем элементы коллекции
//В первом элементе коллекции содержится названия локальных портов,
//во втором - сетевое имя принтера и т.д.
s+=NetwPrinters(i)+" "+NetwPrinters(i+1)+"\n";
i=i+2;
}
WScript.Echo(s); //Выводим сформированные строки на экран
/************* Конец *********************************************/
Листинг 2.49. Вывод списка подключенных сетевых ресурсов (VBScript)
'********************************************************************
' Имя: ListNetworkResources.vbs
' Язык: JScript
' Описание: Вывод подключенных сетевых ресурсов (диски и принтеры)
'********************************************************************
Option Explicit
Dim WshNetwork,s,NetwDrives,i,NetwPrinters ' Объявляем переменные
' Создаем объект WshNetwork
Set WshNetwork = WScript.CreateObject("WScript.Network")
'******** Вывод списка всех подключенных сетевых дисков *********
s="Подключенные сетевые диски:" & vbCrLf & vbCrLf
' Создаем коллекцию с данными о подключенных дисках
Set NetwDrives = WshNetwork.EnumNetworkDrives
i=0
While i<=NetwDrives.Count-2 ' Перебираем элементы коллекции
' В первом элементе коллекции содержится буква диска,
' во втором - сетевое имя ресурса и т.д.
s=s & NetwDrives.Item(i) & " " & NetwDrives.Item(i+1) & vbCrLf
i=i+2
Wend
WScript.Echo s ' Выводим сформированные строки на экран
'******** Вывод списка всех подключенных сетевых принтеров *******
s="Подключенные сетевые принтеры:" & vbCrLf & vbCrLf
' Создаем коллекцию с данными о подключенных принтерах
Set NetwPrinters = WshNetwork.EnumPrinterConnections
i=0
While i<=NetwPrinters.Count-2 ' Перебираем элементы коллекции
' В первом элементе коллекции содержится названия локальных портов,
' во втором - сетевое имя принтера и т.д.
s=s & NetwPrinters.Item(i) & " " & NetwPrinters.Item(i+1) & vbCrLf
i=i+2
Wend
WScript.Echo s 'Выводим сформированные строки на экран
'************* Конец *********************************************
Подключение и отключение сетевых дисков и принтеров
Имеющиеся в локальной сети общедоступные ресурсы (диски и принтеры) можно посредством сценария подключить к рабочей станции для совместного использования. Подключаемому сетевому диску при этом нужно поставить в соответствие незанятую букву локального диска (например, если в системе уже имеются диски С:, D: и Е: (локальные или сетевые), то сетевой диск можно подключить под буквой F: или K:, но не Е:). В случае подключения сетевого принтера можно либо напрямую соединиться с этим принтером (для печати из приложений Windows), либо поставить в соответствие удаленному принтеру локальный порт (для печати из старых приложений MS-DOS).